// Newsprint
// by MARK ROLAND <http://www.markrolanddesign.com>
// September 5, 2005

// Samples the color intensity of each pixel in an image
// and then recreates that image using various sizes of black
// "ink spots".  Use keys 1 -> 9 to change spot size.

            
PImage a;
int step;
color[][] colors;

void setup() {
  size(420,260);
  a = loadImage("lauren_me_beach.jpg"); 
  background(a);
  smooth();
  noStroke();
  colors = new color[width][height];
  
  // sample image
  for(int i=0; i<width; i++){
    for(int j=0; j<height; j++){
      colors[i][j] = get(i,j);  
    }
  }
}
  
void draw() {
  // use keys 1->9 to change spot size
  if(keyPressed && key>48 && key<58){
    step = 2*(10 - 58%key);
    fill(255);
    rect(0,0,width,height);
    render();
  }
}

void render(){
  for(int m=0; m<width; m+=step){
    for(int n=0; n<height; n+=step){
      color c = colors[m][n];
      fill(0);
      ellipseMode(CORNER);
      ellipse(m,n,step*(1-(brightness(c)/255)), step*(1-(brightness(c)/255)));
    }
  }
}